{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-24.05";
    flake-utils.url = "github:numtide/flake-utils";

    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs = {
        nixpkgs.follows = "nixpkgs";
      };
    };
    crane = {
      url = "github:ipetkov/crane";
    };
  };
  outputs = { self, nixpkgs, flake-utils, rust-overlay, crane }:
    flake-utils.lib.eachDefaultSystem
      (system:
        let
          overlays = [ (import rust-overlay) ];
          pkgs = import nixpkgs {
            inherit system overlays;
          };
          # craneLib = crane.lib.${system};
          craneLib = (crane.mkLib pkgs).overrideToolchain rustToolchain;
          rustToolchain = pkgs.rust-bin.stable.latest.default.override {
            extensions = [ "rust-src" "rust-analyzer" ];
          };

          src = craneLib.cleanCargoSource (craneLib.path ./.);
          nativeBuildInputs = with pkgs; [ rustToolchain pkg-config ];
          buildInputs = with pkgs; [ openssl sqlite ];
          commonArgs = {
            inherit src nativeBuildInputs buildInputs;
            pname = "vavbot";
            version ="0.1.0";
          };
          cargoArtifacts = craneLib.buildDepsOnly commonArgs;
          bin = craneLib.buildPackage (commonArgs // { inherit cargoArtifacts; });
          dockerImage = pkgs.dockerTools.streamLayeredImage
            {
              name = "vavbot";
              tag = "latest";
              contents = [ bin pkgs.cacert ];
              config = {
                Cmd = [ "${bin}/bin/vavbot" ];
              };
            };
        in
        with pkgs;
        {
          checks = {
            inherit bin;
            fmt = craneLib.cargoFmt { inherit src; };
            tests = craneLib.cargoNextest (commonArgs // {
              inherit cargoArtifacts;
            });
            clippy = craneLib.cargoClippy (commonArgs // {
              inherit cargoArtifacts;
            });
          };
          packages = {
            inherit bin dockerImage;
            default = bin;
          };
          devShells.default = craneLib.devShell {
            inputsFrom = [ bin ];
          };

        }
      );
}